"Faithful Companion" by Matt Weiner

[in 9:13 pm][out 10:43 pm][in 11:01 pm][out 11:07 pm][in 11:37 pm][out 11:44 pm][in 8:55 pm][out 9:28 pm][in 9:34 pm][out 10:00 pm][in 10:00 pm][out 10:09 pm][in 10:10 pm][out 10:16 pm][in 10:17 pm][out 10:21 pm; these micropauses seem suspicious but they occurred when I was trying to figure out how much time I had left]

Use no scoring.
Use American dialect.
Use the serial comma. 

[Addition so I can publish this online:]Release along with source text and an interpreter.

Include Editable Stored Actions by Ron Newcomb.

When play begins: say "Since a recent vandalism, rumors have it that the Thurnley tomb is haunted. None dare enter, and only the caretaker dares go near it. You have promised her to try to lay the ghost to rest; if you do not return by morning she has promised to try to venture in to recover you."

Chapter - The Ghost

The ghost is a person. 
Ghost spontaneously acting is a truth state that varies.
Persuasion rule: if ghost spontaneously acting is true, persuasion succeeds.

First unsuccessful attempt by the ghost doing something when the ghost is not visible: do nothing.

Check the ghost examining when the ghost cannot see the noun: rule fails.

Unsuccessful attempt by the ghost doing something: 
	say "The ghost goes through the motions of [subjectless form of the current action].".
	
Rule for implicitly taking something when the ghost is the person asked and the ghost is not visible: do nothing.
	
To say subjectless form of (X - a stored action):
	let T be a stored action;
	now T is X;
	now the actor part of T is yourself;
	now the request part of T is false;
	say T. 
	
After the ghost examining something: say "The leaves swirl toward [the noun] as if the form within them is peering closely at it."
After the ghost taking something: say "The leaves swirl around [the noun] and it rises into the air among them, where the ghostly figure's hands might be."
Carry out the ghost opening a door when the player can see the noun: say "The ghost opens [the noun]."
	 
Chapter - Ghost Following Actions

The most recent action is a stored action that varies.
The next most recent action is a stored action that varies.
The third most recent action is a stored action that varies.

Every turn: 
	now the third most recent action is the next most recent action;
	now the next most recent action is the most recent action;
	now the most recent action is the current action;
	now the actor part of the third most recent action is the ghost;
	now the request part of the third most recent action is true;
	if the ghost is on-stage:
		now ghost spontaneously acting is true;
		try the third most recent action;
		now ghost spontaneously acting is false.
	
Chapter - Ghost Frightening Touch Rules

Unsuccessful attempt by the ghost taking something when the reason the action failed is the can't take people's possessions rule:
	say "As the ghost reaches to take [the noun] from you, you fall to the floor in a dead faint.";
	end the story saying "The caretaker finds you in the morning".
	
Before taking something when the ghost encloses the noun:
	say "The thought of reaching to touch the ghost to take [the noun] is too much to bear." instead.
	
Chapter - The Antechamber

The Antechamber is a room. "Visitors used to sit on the bench here to contemplate their mortality. Recently the reminders of their mortality have become all too great. A marble door leads inside." 
The bench is an enterable scenery supporter in the Antechamber. The description of the bench is "[If the ghost is off-stage]The bench is covered with a light drift of leaves. The caretaker has been neglecting this crypt and its environs, though she has promised to recover you if you do not return before dawn.[otherwise]The leaves that were on this bench have assembled themselves into the form of a ghost." Understand "leaves" as the bench when the ghost is off-stage.
An iron key is on the bench. The description is "A heavy iron key that seems to fit the lock of the crypt's door."
The marble door is a locked door. It is scenery. It is inside from the Antechamber. The description is "The inscription on the heavy marble door reads 'I May Have Peace When I Rest.'" The iron key unlocks the marble door. Understand "inscription" as the marble door.

Every turn when (the player holds the key or the turn count is greater than 2) and the ghost is off-stage:
	say "You feel a chill but no wind, yet the leaves fly from the bench and twirl in the air. They seem to limn a human figure in an attitude of expectation, as if your presence has stirred some memories of its own life.";
	now the ghost is in the Antechamber.
	
Understand "leaves/figure/human/limn/spirit/wraith/leaf" as the ghost.

Chapter - The Reliquary

The Reliquary is inside from the marble door. "Before November, jeweled crosses and marble statues adorned this room. It was when the place was ransacked that the trouble started.[paragraph break]A granite door leads inside. It seems to be held shut by three latches of unusual design, bronze, steel, and copper.[paragraph break]The marble door leads back out."

The granite door is a closed scenery door. The granite door is inside from the Reliquary. The description is "The door is a plain slab with three latches. The steel latch is [if the steel latch is open]open[otherwise]closed[end if]; the copper latch is [if the copper latch is open]open[otherwise]closed[end if]; the bronze latch is [if the bronze latch is open]open[otherwise]closed[end if]."

Does the player mean doing something to the granite door in the Reliquary: It is likely.
Does the player mean locking the granite door with the iron key: it is very unlikely.

Does the player mean closing the marble door: it is very likely.
Does the player mean locking the marble door with something: it is very likely.

A latch is a kind of thing. A latch can be open or closed. A latch is usually closed. The bronze latch is a latch. The bronze latch is part of the granite door. The copper latch is a latch. The copper latch is part of the granite door. The steel latch is a latch. The steel latch is part of the granite door. The description of a latch is "This latch is designed so that merely pushing it will open it, and pushing it again in the same way will close it again. It is currently [if open]open[otherwise]closed[end if]."

Instead of an actor opening the granite door when a latch is closed: if the person asked is the player, say "The granite door won't open when [the list of closed latches] [if more than one latch is closed]are[otherwise]is[end if] closed."

Before an actor opening, closing, switching on, rubbing, touching, pulling, turning, or switching off a latch: try the actor pushing the noun instead.

Carry out an actor pushing a latch:
	if the noun is closed:
		now the noun is open;
	otherwise:
		now the noun is closed.
		
After pushing a closed latch:
	say "You push [the noun] closed."
After pushing an open latch:
	say "You push [the noun] open."
	
After the ghost pushing a closed latch:
	if the ghost is visible, say "The ghost pushes [the noun] closed."
After the ghost pushing an open latch:
	if the ghost is visible, say "The ghost pushes [the noun] open."	

The Crypt is inside from the granite door. "The sconces on the walls have been smashed, and the [coffin] gapes open in the middle of the crypt.[paragraph break]The granite door leads back out."

The sconces are scenery in the Crypt. Understand "sconce" as the sconces. First instead of doing something when the current action involves the sconces: say "Not your concern. The caretaker will attend to the ruined sconces, if you can attend to the ghost."

The coffin is an enterable open unopenable scenery container in the Crypt. The description of the coffin is "[if the lid is not part of the coffin]The massive coffin gapes open, its still intact hinges missing the lid that would fit into them. An expanse of decayed satin lines its bottom, a few poor bones scattered around its edges.[otherwise if the coffin is open]The coffin stands open.[otherwise]The coffin is shut." Understand "hinges" as the coffin. Understand "decayed" and "satin" as the coffin when the coffin is open.

Some bones are in the coffin. They are fixed in place. The description of the bones is "Poor things...." Understand "corpse/body/bone" as the bones. Instead of taking the bones: say "They are where they belong." 

The heavy lid is in the Crypt. "The coffin's heavy leaden lid lies on the floor." The description of the heavy lid is "Made of solid lead, this lid looks to heavy to lift by yourself. But no one dares accompany you to this tomb." Understand "lead/leaden" as the heavy lid.

Lid lifted this turn is a truth state that varies. Last every turn: now lid lifted this turn is false.

Instead of an actor putting the lid on something:
	try the actor taking the lid.

Instead of taking the lid:
	say "You strain to lift the lid, but you can only raise one edge of it.";
	now lid lifted this turn is true.
	
Understand "lift [something]" as taking.
	
Instead of the the ghost taking the lid when lid lifted this turn is false and the lid is not part of the coffin:
	say "The ghost whirls around one edge of the lid, which just rises from the floor. But the lid soon falls back.";
	rule succeeds.
	
Instead of the ghost taking the lid when lid lifted this turn is true and the lid is not part of the coffin:
	say "The ghost whirls around the edge of the lid that you are holding, and almost without your willing it the lid rises into the air. Before you realize that you have put it down, the lid stands upright on the coffin's hinges.";
	now the lid is part of the coffin;
	now the coffin is openable;
	rule succeeds.
	
Instead of the ghost taking the lid when the lid is part of the coffin:
	say "The ghost goes through the motions of picking up the lid, but it does not budge from its hinges.";
	rule succeeds.

Instead of an actor opening the lid when the lid is part of the coffin:
	try the actor opening the coffin.
Instead of an actor closing the lid when the lid is part of the coffin:
	try the actor closing the coffin.
	
Every turn when the player is in the closed coffin:
	say "With mounting panic you realize that you cannot open the coffin from the inside. Even if the air in here lasts till morning, the caretaker is unlikely to open this coffin in search of you.";
	end the story saying "You add your bones to those already there".

Every turn when the ghost is in the closed coffin and the player is not in the closed coffin:
	say "You hear the leaves swirling in the coffin, then all at once they stop. The ghost is at rest where its bones lie.";
	end the story finally saying "Your faithful companion has been laid to rest".
	
After entering the coffin:
	say "Careful not to disturb the bones, you climb into the coffin."
	
After exiting from the coffin:
	say "You gingerly climb back out of the coffin."