Tea and Toast — 15 of 31

Section - Major Things and Their Descriptions

A thing can be major. The sink, the cabinet, the countertop, and the table are major. [Big loci for writing the room description.]

After writing a paragraph about a major thing (called the fixture):

now everything enclosed by the fixture is mentioned.

For writing a paragraph about the countertop:

if a significant thing is on the countertop:

say "[countertop things description]";

otherwise if something is on the countertop:

say "The countertop is bare of anything you need right now.";

otherwise:

say "For some reason the countertop is completely bare."

To say countertop things description:

let L be the list of significant unpluggable things on the countertop; [If I don't create a temporary variable the is-are of phrase isn't called, for reasons I do not understand]

say "[if a significant unpluggable thing is on the countertop][A prominence-ordered L] [is-are of L] scattered on the counter. [end if][If a pluggable thing is on the countertop][The prominence-ordered list of pluggable things on the countertop] sit[s of the list of pluggable things on the countertop] by the wall outlet.[end if]"

Carry out examining the countertop:

say "The countertop has a few nicks from vegetables sliced straight on it when no cutting board was at hand, a faint brown tinge from a teabag left to bleed out, all the little marks of inhabitation. [if something significant is on the countertop][countertop things description][otherwise][line break]";

rule succeeds. [These have to be carry out rules rather than instead rules so tchotchkes in the vicinity can get noticed, and the rules have to succeed so we can go to the After rulebook where tchotchkes get noticed.]

To say s of (catalogue - a list of things):

if the number of entries in the catalogue is 1, say "s".

To say is-are of (catalogue - a list of things):

if the number of entries in the catalogue is 1:

say "is";

otherwise:

say "are".

To say cabinet things description:

if the cabinet are open:

if a significant thing is in the cabinet:

say "On the cabinet shelves [is-are a list of significant things in the cabinet].";

otherwise:

say "The cabinet is full of glasses, bowls, tiny trays[first time], an inexplicable rubber koosh[only]; the sort of thing you might need for another meal[first time]. Well, not the koosh[only].";

now the koosh is significant; [don't want to notice it again]

For writing a paragraph about the open cabinet:

say cabinet things description.

For writing a paragraph about the closed cabinet:

say "The closed cabinets are above the countertop."

Carry out examining the closed cabinet:

say "Perhaps when brand new the cabinets gleamed white, but years of cooking smoke and steam have dulled their shine. A relief, really.";

rule succeeds.

Carry out examining the open cabinet:

say cabinet things description;

rule succeeds.

Report opening (this is the reveal significant things in the interior rule):

if the noun is an opaque container and a significant thing is in the noun and the noun does not enclose the player:

let L be the list of significant things in the noun;

say "You open [the noun]. In [it-them of the noun] [is-are a list of significant things in the noun]." instead.

The reveal significant things in the interior rule is listed instead of the reveal any newly visible interior rule in the report opening rulebook.

For writing a paragraph about the table:

if a significant thing is on the table:

let L be the list of significant things on the table;

say "[The list of significant things on the table] [is-are of L] on the table.";

otherwise:

say "The table awaits its tea and toast."

Carry out examining the table:

say "It's the light brown wooden table from Lily's parents['] kitchen. They got a new one and it was nicer than anything you had. [run paragraph on]";

carry out the writing a paragraph about activity with the table;

rule succeeds.

For writing a paragraph about the sink:

if the sink is switched on:

say "Water is rushing from the sink's faucet.";

otherwise:

say "The sink is off."

Carry out examining the sink: carry out the writing a paragraph about activity with the sink instead.