Tea and Toast — 20 of 31

Section - Specific Mission Assessment Rules and Prompting Rules

[These rules are together to make it easier to keep track of them. It's a lot easier to see how to prompt something when you can see how it's assessed.]

Mission assessment rules is a thing based rulebook producing a mission-criticality.

Prompting something is an activity on things.

For prompting a thing (called the item): say "It seems to you that there's something you can do with [the item]...." [Hopefully this will never actually print.]

First for prompting a thing (called the item) when the player cannot see the item:

if the item is in something (called the sheath):

say "It occurs to you that [the item] [is-are] in [the sheath]. You might need it.";

otherwise:

say "There's [an item] around here somewhere, isn't there?"

A mission assessment rule for a mission-irrelevant thing: rule succeeds with result irrelevant.

A mission assessment rule for the toaster:

if the toaster is switched on or a toasted bread slice is on-stage: [if the toaster is toasting or toast is made, nothing more need be done]

rule succeeds with result fulfilled;

otherwise if every bread slice is off-stage: [nothing to toast yet]

rule succeeds with result pending;

otherwise:

rule succeeds with result critical.

For prompting the toaster:

if the toaster is unplugged:

say "You'll have to plug in the toaster.";

otherwise unless a bread slice is in the toaster:

say "You'll want to put bread in the toaster.";

otherwise:

say "The toaster is ready to be switched on."

A mission assessment rule for the kettle:

if the kettle is switched on or the hot water is on-stage or the hot tea is on-stage: [the kettle has made its hot water or is doing so]

rule succeeds with result fulfilled;

otherwise:

rule succeeds with result critical.

For prompting the kettle:

if the kettle is not filled with something:

say "You'll have to fill the kettle up with water.";

otherwise if the kettle is unplugged:

say "You'll have to plug in the kettle.";

otherwise:

say "The kettle is ready to be switched on."

A mission assessment rule for the cold water:

if the kettle is filled with cold water or the mission status of the kettle is fulfilled:

rule succeeds with result fulfilled;

otherwise:

rule succeeds with result critical.

For prompting the cold water:

say "You'll have to fill the kettle up with water."

A mission assessment rule for the loose tea:

if the tea leaves are in the tea strainer:

rule succeeds with result fulfilled;

otherwise:

rule succeeds with result critical.

For prompting the loose tea:

say "There isn't any tea in the tea strainer! You'll have to put the loose tea in the strainer."

A mission assessment rule for the tea strainer:

if the tea leaves are in the strainer and the strainer is in the teapot:

rule succeeds with result fulfilled;

if the hot tea is on-stage:

rule succeeds with result fulfilled;

rule succeeds with result critical. [could've used this format instead of the "otherwises" in the above rules too.]

For prompting the tea strainer:

if the tea leaves are not in the tea strainer:

say "The tea strainer doesn't have any tea in it! You'll have to fill the tea strainer up.";

otherwise:

say "You'll have to put the strainer in the teapot."

A mission assessment rule for the hot water:

if the hot tea is on-stage:

rule succeeds with result fulfilled;

if the teapot is filled with hot water:

rule succeeds with result fulfilled;

if the hot water is off-stage:

rule succeeds with result pending;

if the strainer is not in the teapot:

rule succeeds with result pending;

rule succeeds with result critical.

For prompting the hot water:

say "You can pour the hot water into the teapot to make tea."

A mission assessment rule for the teapot:

if the hot tea is on-stage:

rule succeeds with result fulfilled;

if the teapot is filled with hot water and the strainer is in the teapot:

rule succeeds with result fulfilled;

if the hot water is off-stage:

rule succeeds with result pending;

if the tea leaves are not in the strainer:

rule succeeds with result pending;

rule succeeds with result critical.

For prompting the teapot:

if the tea strainer is not in the teapot:

say "You'll have to put the strainer in the teapot.";

otherwise:

say "The teapot is ready to be filled with hot water."

A mission assessment rule for the hot tea:

if the hot tea is off-stage:

rule succeeds with result pending;

if a teacup is filled with hot tea:

rule succeeds with result fulfilled;

rule succeeds with result critical.

For prompting the hot tea:

say "The hot tea is ready to pour into a teacup."

A mission assessment rule for the bread knife:

if a bread slice is on-stage:

rule succeeds with result fulfilled;

rule succeeds with result critical.

For prompting the bread knife:

say "You could cut some bread with the bread knife."

A mission assessment rule for the loaf of bread:

if a bread slice is on-stage:

rule succeeds with result fulfilled;

rule succeeds with result critical.

For prompting the loaf of bread: say "You could cut some bread."

A mission assessment rule for a teacup:

if the hot tea is off-stage:

rule succeeds with result pending;

if a teacup is filled with hot tea:

rule succeeds with result fulfilled;

rule succeeds with result critical.

For prompting a teacup:

say "The teacup longs to be filled with tea."

A mission assessment rule for a bread slice:

if every bread slice is off-stage:

rule succeeds with result pending;

if a bread slice is toasted:

rule succeeds with result fulfilled;

if a bread slice is in the toaster:

rule succeeds with result fulfilled;

rule succeeds with result critical.

For prompting a bread slice:

say "You could put a slice of bread in the toaster."